GoGoGadgetScott :: Computers :: Custom Testing Class

Download Custom Testing Class (vbs file)

'**********************************************************
'FILE: cTesting.vbs
'VERSION: 1.0
'CREATED: 05/10/2004
'UPDATED: 05/13/2004
'AUTHOR: Scott Greenberg
'COMPANY: SG Technology
'WEBSITE: http://gogogadgetscott.info
'DECRIPTION: A custom VBScript testing class
'COMMENT: N/A
'**********************************************************
'=====================================
'Class Usage
'=====================================
sTestFolder = "D:\Programming\Scripts\VBScripting\classes"
'Include sTestFolder & "\cTesting.vbs"
'SwitchCScript()
'Example()
Sub Include(sScriptPath)
Dim m_FSO, m_oFile
Set m_FSO = CreateObject ("Scripting.Filesystemobject")
If m_FSO.FileExists (sScriptPath) Then
Set m_oFile = m_FSO.OpenTextFile (sScriptPath)
ExecuteGlobal m_oFile.ReadAll ()
m_oFile.Close
Set m_oFile = Nothing
End If
Set m_FSO = Nothing
End Sub
Sub Example()
'Create New intencses of classes
Set timer1 = New cTimer
Set Out = New cOutput
'Clear any prior output
Out.Clear
MsgBox "Start"
'Run a few tests With timer
With timer1
.StartTimer()
WScript.Sleep 1000
.StopTimer()
'Print results
Out.WriteLine timer1.Elapsed()
.StartTimer()
WScript.Sleep 2000
.StopTimer()
Out.WriteLine .Elapsed()
End With
'Create header file
Set Head = New cOutput
With Head
.File = sTestFolder & "\head.txt"
.Clear
.WriteLine "VBScript Custom Testing Class"
.WriteLine "By: SG Technology"
End With
'Create footer file
Set Foot = New cOutput
With Foot
.File = sTestFolder & "\foot.txt"
.Clear
.WriteLine "VBScript Custom Testing Class"
End With
'Apply header And footer To output file
Out.Header = Head.File
Out.Footer = Foot.File
'Show output file
Out.View
'Delete header And footer files
Head.Delete
Foot.Delete
MsgBox "Done"
End Sub
'=====================================
'Execute options
'=====================================
'Switch To debuging
Sub debug()
sCmd = "cscript.exe """ & WScript.scriptfullname & """ //X " & GetArgs
Execute sCmd
End Sub
Sub SwitchCScript()
sCmd = "cscript.exe """ & WScript.scriptfullname & """ " & GetArgs
Execute sCmd
End Sub
Private Function GetArgs()
Set oArgs = WScript.Arguments
For i = 0 To oArgs.Count - 1
GetArgs = GetArgs & " " & oArgs(i)
Next
End Function
Private Sub Execute(sCmd)
Set Sh = CreateObject ("WScript.Shell")
If (InStr (LCase (WScript.FullName), "wscript") <> 0) Then
Sh.Run sCmd, 1, False
WScript.Quit -1
End If
End Sub
'=====================================
'Timer class
'=====================================
Class cTimer
Private timStart, timElapsed, nFrequency, m_bRunning
Private Sub Class_Initialize()
nFrequency = 0
End Sub
'Starts the Counter
Public Sub StartTimer()
timElapsed = 0 'Reset Counter
m_bRunning = True
timStart = Timer
End Sub
'Ends the Counter
Public Sub StopTimer()
timElapsed = GetElapsedTime 'Store this Value
m_bRunning = False
End Sub
'Returns Elapsed time
Public Property Get Elapsed()
If m_bRunning Then
Elapsed = GetElapsedTime 'Return Intermediate Time
Else
Elapsed = timElapsed 'Return last counter's timing
End If
End Property
'Calculates the Elapsed Time
Private Function GetElapsedTime()
timEnd = Timer
GetElapsedTime = timEnd - timStart
End Function
End Class
'=====================================
'Output class
'=====================================
Class cOutput
Private m_FSO, m_sOutFile, m_fOutput, m_bRunning, _
m_sHeader, m_sFooter, m_bWritten
Private Sub Class_Initialize()
Set m_FSO = CreateObject ("Scripting.FileSystemObject")
End Sub
Private Sub OpenFile(iomode)
Close ()
Set m_fOutput = m_FSO.OpenTextFile(Me.File, iomode, True )
End Sub
'Close output file handle
Private Sub Close ()
If IsEmpty (m_sOutFile) And IsObject (m_fOutput) Then
m_fOutput.Close
End If
Set m_fOutput = Nothing
End Sub
'Apply header And footer
Private Sub WriteFile()
If m_sHeader <> "" Then
OpenFile 1 'Open For reading
sTemp = m_fOutput.ReadAll
Clear()
m_fOutput.Write m_FSO.OpenTextFile (m_sHeader).ReadAll
m_fOutput.WriteLine ""
m_fOutput.Write sTemp
End If
If m_sFooter <> "" Then
m_fOutput.Write m_FSO.OpenTextFile (m_sFooter).ReadAll
End If
m_bWritten = True
End Sub
'Close everything
Private Sub Class_Terminate()
If m_bWritten = False Then WriteFile()
Close ()
Set m_FSO = Nothing
End Sub
'Class Property 's
Public Property Let File(sFilePath)
m_sOutFile = sFilePath
End Property
Public Property Get File()
If IsEmpty (m_sOutFile) Then
m_sOutFile = m_FSO.GetParentFolderName (WScript.ScriptFullName ) & _
"\Testing.txt"
End If
File = m_sOutFile
End Property
'File To be append To top of output file
'i.e. head of html document
Public Property Let Header(sFilePath)
If m_FSO.FileExists (sFilePath) Then
m_sHeader = sFilePath
End If
End Property
Public Property Get Header()
Header = m_sHeader
End Property
'File To be append To bottom of output file
Public Property Let Footer(sFilePath)
If m_FSO.FileExists (sFilePath) Then
m_sFooter = sFilePath
End If
End Property
Public Property Get Footer()
Footer = m_sFooter
End Property
'Public functions
Public Sub WriteLine(sLine)
If IsObject (m_fOutput) = False Then
OpenFile 8 'Open For appending
End If
m_fOutput.WriteLine sLine
m_bWritten = False
End Sub
'Clear any previous contents of output file
Public Sub Clear()
OpenFile 2 'Open For writing
End Sub
'View output file
'Note: Header And footer will be duplicate If any
'WriteLine Is invoked after View
Public Sub View()
WriteFile()
Close ()
Dim Sh
Set Sh = WScript.CreateObject ("WScript.Shell")
Sh.Run """" & m_sOutFile & """"
Set Sh = Nothing
End Sub
Public Sub Delete()
Close ()
m_FSO.DeleteFile m_sOutFile
End Sub
End Class

Download Custom Testing Class (vbs file)